Origins: quest ending adjustments

README.md

@@ -251,7 +251,7 @@
 * Lethal grenade hint string no longer displays "ammo" after purchasing
 
 ## Mystery Box
-* Players will now get every weapon they can before getting duplicates
+* Players will get every weapon they can before getting duplicates
 * Decreased weapon pickup time from 12 seconds to 9 seconds
 * Moves to new location instantly
 * Special sound no longer plays when obtaining the Ray Gun
@@ -578,15 +578,17 @@
 * Der Wunderfizz: increased cost from 1500 to 2500
 * Der Wunderfizz: all perks have an equal chance of being obtained
 * Rituals of the Ancients: spend points challenge reward changed from Double Tap perk to a random perk that the player does not have (perk does not change if reward is reopened)
-* Soul boxes: decreased kill requirement from 30 to 20
+* Soul boxes: decreased number of souls to close from 30 to 20
 * Dig spots: decreased number of digs to obtain golden shovel from 30 to 20
 * Dig spots: changed number of digs to obtain golden helmet to 40 (normally 5% chance to obtain after obtaining golden shovel)
 * Perk bottle dig spots: give random perk
 * Perk bottle dig spots: visible and diggable without Zombie Blood
 * Perk bottle dig spots: increased number of rounds for next dig spot to spawn from 1 to 4
-* Ascend from darkness quest step: staffs can be placed at any staff holder
+* Quest (ascend from darkness step): staffs can be placed at any staff holder
-* Ascend from darkness quest step: fixed an issue where staffs were able to be picked up at their build location when placed in the staff holders
+* Quest (ascend from darkness step): fixed an issue where staffs were able to be picked up at their build location when placed in the staff holders
-* Rain fire quest step: button no longer deactivates
+* Quest (rain fire step): button no longer deactivates
+* Quest (raise hell step): zombies in The Crazy Place get knocked down during the screen flash after collecting all souls
+* Quest (freedom step): teleport trigger can be triggered without looking at it
 
 ## Game Modes
 

scripts/zm/replaced/zm_tomb_ee_main_step_8.gsc

@@ -0,0 +1,68 @@
+#include common_scripts\utility;
+#include maps\mp\_utility;
+#include maps\mp\zombies\_zm_utility;
+#include maps\mp\zombies\_zm_sidequests;
+#include maps\mp\zm_tomb_ee_main;
+#include maps\mp\zm_tomb_utility;
+#include maps\mp\zm_tomb_vo;
+#include maps\mp\gametypes_zm\_hud_util;
+#include maps\mp\gametypes_zm\_hud;
+#include maps\mp\zm_tomb_chamber;
+#include maps\mp\zm_tomb_ee_main_step_8;
+
+init()
+{
+    declare_sidequest_stage( "little_girl_lost", "step_8", ::init_stage, ::stage_logic, ::exit_stage );
+}
+
+stage_logic()
+{
+    level notify( "tomb_sidequest_complete" );
+
+    s_pos = getstruct( "player_portal_final", "targetname" );
+
+    foreach ( player in get_players() )
+    {
+        if ( player is_player_in_chamber() )
+            player thread fadetoblackforxsec( 0, 0.3, 0.5, 0.5, "white" );
+    }
+
+    a_zombies = getaispeciesarray( level.zombie_team, "all" );
+    foreach ( zombie in a_zombies )
+    {
+        if ( is_point_in_chamber( zombie.origin ) && !is_true( zombie.is_mechz ) && is_true( zombie.has_legs ) && is_true( zombie.completed_emerging_into_playable_area ) )
+        {
+            zombie.v_punched_from = s_pos.origin;
+            zombie animcustom( maps\mp\zombies\_zm_weap_one_inch_punch::knockdown_zombie_animate );
+        }
+    }
+
+    wait 0.5;
+    level setclientfield( "ee_sam_portal", 2 );
+    level notify( "stop_random_chamber_walls" );
+    a_walls = getentarray( "chamber_wall", "script_noteworthy" );
+
+    foreach ( e_wall in a_walls )
+    {
+        e_wall thread maps\mp\zm_tomb_chamber::move_wall_up();
+        e_wall hide();
+    }
+
+    flag_wait( "ee_quadrotor_disabled" );
+    wait 1;
+    level thread ee_samantha_say( "vox_sam_all_staff_freedom_0" );
+
+    t_portal = tomb_spawn_trigger_radius( s_pos.origin, 100, 1 );
+    t_portal.hint_string = &"ZM_TOMB_TELE";
+    t_portal thread waittill_player_activates();
+    level.ee_ending_beam_fx = spawn( "script_model", s_pos.origin + vectorscale( ( 0, 0, -1 ), 300.0 ) );
+    level.ee_ending_beam_fx.angles = vectorscale( ( 0, 1, 0 ), 90.0 );
+    level.ee_ending_beam_fx setmodel( "tag_origin" );
+    playfxontag( level._effect["ee_beam"], level.ee_ending_beam_fx, "tag_origin" );
+    level.ee_ending_beam_fx playsound( "zmb_squest_crystal_sky_pillar_start" );
+    level.ee_ending_beam_fx playloopsound( "zmb_squest_crystal_sky_pillar_loop", 3 );
+    flag_wait( "ee_samantha_released" );
+    t_portal tomb_unitrigger_delete();
+    wait_network_frame();
+    stage_completed( "little_girl_lost", level._cur_stage_name );
+}

scripts/zm/zm_tomb/zm_tomb_reimagined.gsc

@@ -8,6 +8,9 @@
 #include scripts\zm\replaced\zm_tomb_quest_elec;
 #include scripts\zm\replaced\zm_tomb_quest_fire;
 #include scripts\zm\replaced\zm_tomb_quest_ice;
+#include scripts\zm\replaced\zm_tomb_ee_main_step_2;
+#include scripts\zm\replaced\zm_tomb_ee_main_step_3;
+#include scripts\zm\replaced\zm_tomb_ee_main_step_8;
 #include scripts\zm\replaced\zm_tomb_capture_zones;
 #include scripts\zm\replaced\zm_tomb_challenges;
 #include scripts\zm\replaced\zm_tomb_craftables;
@@ -38,6 +41,7 @@ main()
 	replaceFunc(maps\mp\zm_tomb_ee_main_step_2::create_robot_head_trigger, scripts\zm\replaced\zm_tomb_ee_main_step_2::create_robot_head_trigger);
 	replaceFunc(maps\mp\zm_tomb_ee_main_step_2::remove_plinth, scripts\zm\replaced\zm_tomb_ee_main_step_2::remove_plinth);
 	replaceFunc(maps\mp\zm_tomb_ee_main_step_3::fire_link_cooldown, scripts\zm\replaced\zm_tomb_ee_main_step_3::fire_link_cooldown);
+    replaceFunc(maps\mp\zm_tomb_ee_main_step_8::init, scripts\zm\replaced\zm_tomb_ee_main_step_8::init);
     replaceFunc(maps\mp\zm_tomb_capture_zones::setup_capture_zones, scripts\zm\replaced\zm_tomb_capture_zones::setup_capture_zones);
     replaceFunc(maps\mp\zm_tomb_challenges::challenges_init, scripts\zm\replaced\zm_tomb_challenges::challenges_init);
     replaceFunc(maps\mp\zm_tomb_craftables::init_craftables, scripts\zm\replaced\zm_tomb_craftables::init_craftables);